refactor(nvim): move config out of module

2026-09-28 21:18:11 +02:00
parent 178a51d75e
commit aee9682d64
82 changed files with 3 additions and 3 deletions
@@ -0,0 +1,292 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    nixCats.url = "github:BirdeeHub/nixCats-nvim";
+
+    plugins-shipwright-nvim = {
+      url = "github:rktjmp/shipwright.nvim";
+      flake = false;
+    };
+    # plugins-m-taskwarrior-d-nvim = {
+    #   url = "github:huantrinh1802/m_taskwarrior_d.nvim";
+    #   flake = false;
+    # };
+    plugins-beancount-nvim = {
+      url = "github:polarmutex/beancount.nvim";
+      flake = false;
+    };
+    plugins-tailwind-fold-nvim = {
+      url = "github:razak17/tailwind-fold.nvim";
+      flake = false;
+    };
+    plugins-nvimkit-nvim = {
+      url = "github:jamesblckwell/nvimkit.nvim";
+      flake = false;
+    };
+
+  };
+
+  outputs =
+    {
+      nixpkgs,
+      nixCats,
+      ...
+    }@inputs:
+    let
+      inherit (nixCats) utils;
+      luaPath = ./.;
+      forEachSystem = utils.eachSystem nixpkgs.lib.platforms.all;
+      extra_pkg_config = {
+        allowUnfreePredicate =
+          pkg:
+          builtins.elem (nixpkgs.lib.getName pkg) [
+            "vim-sandwich"
+            "jupytext.nvim"
+            "eyeliner.nvim"
+            "context_filetype.vim"
+            "editorconfig-vim"
+            "unicode.vim"
+            "quarto-nvim"
+            "vim-openscad"
+            "lsp_lines.nvim"
+            "nvim-highlight-colors"
+            "nvim-lint"
+          ];
+      };
+
+      mkDependencyOverlays = [
+        (utils.standardPluginOverlay inputs)
+        (_: prev: {
+          luajitPackages = prev.luajitPackages.overrideScope (
+            _: lprev: {
+              neotest = lprev.neotest.overrideAttrs (_: {
+                doCheck = false;
+              });
+            }
+          );
+        })
+      ];
+
+      categoryDefinitions =
+        {
+          pkgs,
+          categories,
+          ...
+        }:
+        let
+          themes = import ./themes.nix pkgs;
+        in
+        {
+          lspsAndRuntimeDeps = with pkgs; {
+            general = [
+              nodejs_24
+              black
+              clang
+              clang-tools
+              curl # → plenary-nvim
+              delta
+              emmet-language-server
+              eslint_d
+              fd
+              gawk
+              gdtoolkit_4
+              hadolint
+              helm-ls
+              isort
+              lua-language-server
+              nixd
+              nixfmt
+              prettier
+              typescript-language-server
+              ormolu
+              prettierd
+              rust-analyzer
+              rustfmt
+              shellcheck-minimal
+              stylelint
+              stylua
+              tree-sitter
+              tailwindcss-language-server
+              typescript-language-server
+              vscode-langservers-extracted
+              vtsls
+              yaml-language-server
+              yamllint
+            ];
+          };
+
+          startupPlugins = {
+            general =
+              with pkgs.vimPlugins;
+              [
+                ## plug
+                vim-plug
+                vim-sandwich
+                context_filetype-vim
+                editorconfig-vim
+                vim-snippets
+                unicode-vim
+                vim-css-color
+                quarto-nvim
+                vimtex
+                wiki-vim
+                vim-pandoc
+                vim-pandoc-syntax
+                # TODO: ferrine/md-img-paste.vim
+                # TODO: supercollider/scvim
+                # TODO: tidalcycles/vim-tidal
+                vim-glsl
+                # TODO: timtro/glslView-nvim
+                # TODO: sirtaj/vim-openscad
+                jupytext-nvim
+                vim-openscad
+                ## paq
+                eyeliner-nvim
+                fzf-lua
+                ltex_extra-nvim
+                nvim-lspconfig
+                lsp_lines-nvim
+                lsp-progress-nvim
+                neodev-nvim
+                SchemaStore-nvim
+                nvim-lint
+                conform-nvim
+                luasnip
+                cmp_luasnip
+                nvim-cmp
+                cmp-nvim-lsp
+                cmp-buffer
+                cmp-path
+                plenary-nvim
+                nui-nvim
+                trouble-nvim
+                lush-nvim
+                pkgs.neovimPlugins.shipwright-nvim
+                nvim-treesitter.withAllGrammars
+                nvim-treesitter-textobjects
+                # nvim-treesitter-context
+                nvim-ts-context-commentstring
+                # theHamsta/crazy-node-movement
+                treesj
+                sniprun
+                gitsigns-nvim
+                nvim-highlight-colors
+                pkgs.neovimPlugins.tailwind-fold-nvim
+                auto-session
+                nvim-dbee
+                image-nvim
+                pkgs.neovimPlugins.beancount-nvim
+                pkgs.neovimPlugins.nvimkit-nvim
+                codecompanion-nvim
+                helm-ls-nvim
+                kitty-scrollback-nvim
+                fidget-nvim
+                rustaceanvim
+                # pkgs.neovimPlugins.m-taskwarrior-d-nvim
+                claudecode-nvim
+                snacks-nvim
+              ]
+              ++ themes.${categories.colorscheme or "zenwritten"};
+          };
+
+          optionalPlugins = {
+            general = with pkgs.vimPlugins; [
+            ];
+          };
+
+          sharedLibraries = {
+            general = [ ];
+          };
+
+          environmentVariables = { };
+        };
+
+      packageDefinitions = {
+        nvim = _: {
+          settings = {
+            suffix-path = true;
+            suffix-LD = true;
+            wrapRc = true;
+            aliases = [ "vim" ];
+          };
+          categories = {
+            general = true;
+            colorscheme = "zenwritten";
+          };
+        };
+      };
+      defaultPackageName = "nvim";
+    in
+
+    forEachSystem (
+      system:
+      let
+        dependencyOverlays = mkDependencyOverlays;
+        nixCatsBuilder = utils.baseBuilder luaPath {
+          inherit
+            nixpkgs
+            system
+            dependencyOverlays
+            extra_pkg_config
+            ;
+        } categoryDefinitions packageDefinitions;
+        defaultPackage = nixCatsBuilder defaultPackageName;
+        pkgs = import nixpkgs { inherit system; };
+      in
+      {
+        packages = utils.mkAllWithDefault defaultPackage;
+
+        devShells = {
+          default = pkgs.mkShell {
+            name = defaultPackageName;
+            packages = [ defaultPackage ];
+            inputsFrom = [ ];
+            shellHook = "";
+          };
+        };
+
+      }
+    )
+    // (
+      let
+        nixosModule = utils.mkNixosModules {
+          moduleNamespace = [ defaultPackageName ];
+          inherit
+            defaultPackageName
+            luaPath
+            categoryDefinitions
+            packageDefinitions
+            extra_pkg_config
+            nixpkgs
+            ;
+          dependencyOverlays = mkDependencyOverlays;
+        };
+        homeModule = utils.mkHomeModules {
+          moduleNamespace = [ defaultPackageName ];
+          inherit
+            defaultPackageName
+            luaPath
+            categoryDefinitions
+            packageDefinitions
+            extra_pkg_config
+            nixpkgs
+            ;
+          dependencyOverlays = mkDependencyOverlays;
+        };
+      in
+      {
+
+        overlays = utils.makeOverlays luaPath {
+          inherit nixpkgs extra_pkg_config;
+          dependencyOverlays = mkDependencyOverlays;
+        } categoryDefinitions packageDefinitions defaultPackageName;
+
+        nixosModules.default = nixosModule;
+        homeModules.default = homeModule;
+
+        inherit utils nixosModule homeModule;
+        inherit (utils) templates;
+      }
+    );
+
+}